Zu Content springen
Deutsch
Anmelden
https://cslonz.de/
  • Es gibt keine Vorschläge, da das Suchfeld leer ist.

IPRO- Fehler beim überschreiben der DaSi und DaSi auf "automatisch" setzen.

Was kann ich machen wenn der die DaSi nicht gemacht werden kann weil IPRO nicht automatisch den Ordner umbenennt?

Wir erstellen uns eine Batchdatei und merken uns den Speicherpfad.

@echo off
rem +---------------------------------------------------------------------+
rem | |
rem | Umbenennen und Abschöpfen von IPRO-Datensicherungen, um Raum für |
rem | eine neue Sicherung zu schaffen. |
rem | |
rem | |
rem | Aufruf: DaSi_neu <Pfad>\IPROSAVE <Anzahl Sicherungen (min. 2)> |
rem | |
rem | z.B.: DaSi_neu X:\IPROSAVE 25 |
rem | |
rem +---------------------------------------------------------------------+
rem | |
rem | Autor: Roland Volkmann |
rem | Date: 02.07.2015 |
rem | |
rem | Copyright (C) IPRO GmbH Leonberg 2013-2016 |
rem | |
rem +---------------------------------------------------------------------+


if "%1"=="" goto Fehler_Aufruf
if "%2"=="" goto Fehler_Aufruf

set DaSiPfad=
set DaSiPfad=%~n1%~x1
if not "%DaSiPfad%"=="iprosave" goto Fehler_Pfad

set DaSiPfad=
set DaSiPfad=%~d1%~p1%
if not exist "%DaSiPfad%IPROSAVE" goto quit


set MaxAnzahl=
set /a MaxAnzahl=%2*1
if "%MaxAnzahl%"=="" goto Fehler_Anzahl
if "%MaxAnzahl%"=="0" goto Fehler_Anzahl
if "%MaxAnzahl%"=="1" goto Fehler_Anzahl


set SaveDate=
set SaveDate=%~t1
rem if not "%SaveDate:~2,1%"=="." goto Fehler_Datum
rem if not "%SaveDate:~5,1%"=="." goto Fehler_Datum
rem if not "%SaveDate:~13,1%"==":" goto Fehler_Datum

set NeuName=
set NeuName=%SaveDate:~6,4%%SaveDate:~3,2%%SaveDate:~0,2%_%SaveDate:~11,2%%SaveDate:~-2%
ren "%DaSiPfad%IPROSAVE" "IPROSAVE%NeuName%"


FOR /F "usebackq skip=%MaxAnzahl% delims=*" %%d in (`dir /o-d /b "%DaSiPfad%IPROSAVE????????_????"`) DO (
rd /s /q "%DaSiPfad%%%d"
)

echo %Date% %Time% OK.
goto quit


rem ---------- Fehlerbehandlung ----------
:Fehler_Aufruf
echo.
echo ++ Fehler beim Aufruf!
echo.
echo korrekte Syntax: DaSi_neu {Pfad}\IPROSAVE {max. Anzahl Sicherungen}
echo.
echo z.B.: DaSi_neu X:\IPROSAVE 25
echo.
goto quit

:Fehler_Pfad
echo.
echo ++ Fehlerhafter Pfad: "%DaSiPfad%"
echo.
goto quit

:Fehler_Anzahl
echo.
echo ++ Fehlerhafte Anzahl Sicherungen: "%2"
echo.
goto quit

:Fehler_Datum
echo.
echo ++ Fehlerhaftes Datumsformat: "%SaveDate%"
echo.
goto quit


:quit

Wir kopieren uns den gesamten Code und erstellen uns eine Batch Datei.

Wir öffnen winIPRO

System>Einstellungen>Aufgabenplaner

Doppelklick auf unsere Automatisierung.

 

Wir aktivieren die Aktion nach der Ausführung.

Aktion: Programm/Script ausführen.

Datei: Hier können wir über die drei Punkte unsere erstellte .bat auswählen

Argumente: hier kopieren wir unseren Pfad herein "" nicht vergessen. Die Zahl am Ende sagt aus wie viele Sicherungen gespeichert werden sollen (zB. 9 Sicherungen bleiben bestehen)